ESET_Apt_Windows_Invisimole_DNS_Downloader

private rule ESET_Invisimole_Blob_PRIVATE
{
	meta:
		description = "Detects InvisiMole blobs by magic values"
		author = "ESET Research"
		id = "6a179d91-50f1-5400-b141-0f162efd2431"
		date = "2021-05-17"
		modified = "2021-05-17"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/invisimole/invisimole.yar#L34-L52"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		logic_hash = "8bddaf874da58fbe6362498f8979b511f39531fe2b98d4be8c099bdafb6d0067"
		score = 75
		quality = 80
		tags = ""
		license = "BSD 2-Clause"
		version = "1"

	strings:
		$magic_old_32 = {F9 FF D0 DE}
		$magic_old_64 = {64 FF D0 DE}
		$magic_new_32 = {86 DA 11 CE}
		$magic_new_64 = {64 DA 11 CE}

	condition:
		($magic_old_32 at 0 ) or ( $magic_old_64 at 0 ) or ( $magic_new_32 at 0 ) or ( $magic_new_64 at 0 )
}

rule ESET_Apt_Windows_Invisimole_DNS_Downloader : FILE
{
	meta:
		description = "InvisiMole DNS downloader"
		author = "ESET Research"
		id = "1caa6c8b-3798-556e-835e-885b7f3f4511"
		date = "2021-05-17"
		modified = "2021-05-17"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/invisimole/invisimole.yar#L140-L170"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		logic_hash = "88d6ed7ec1331153d19afc18473a4be2b214ad8af29fcf7051a2a8e40e088231"
		score = 75
		quality = 80
		tags = "FILE"
		license = "BSD 2-Clause"
		version = "1"

	strings:
		$d = "DnsQuery_A"
		$s1 = "Wireshark-is-running-{9CA78EEA-EA4D-4490-9240-FC01FCEF464B}" xor
		$s2 = "AddIns\\" ascii wide xor
		$s3 = "pcornomeex." xor
		$s4 = "weriahsek.rxe" xor
		$s5 = "dpmupaceex." xor
		$s6 = "TCPViewClass" xor
		$s7 = "PROCMON_WINDOW_CLASS" xor
		$s8 = "Key%C"
		$s9 = "AutoEx%C" xor
		$s10 = "MSO~"
		$s11 = "MDE~"
		$s12 = "DNS PLUGIN, Step %d" xor
		$s13 = "rundll32.exe \"%s\",StartUI"

	condition:
		(( uint16( 0 ) == 0x5A4D ) or ESET_Invisimole_Blob_PRIVATE ) and $d and 5 of ( $s* )
}