YARA · ESET malware-ioc

ESET_Apt_Windows_Invisimole

InvisiMole magic values, keys and strings

APT / threat actorInvisimoleESET malware-iocBSD 2-Clause LicenseCompiles with YARA-X

Author: ESET Research
Date: 2021-05-17
Score / Quality: 75 / 80

What this rule detects

InvisiMole magic values, keys and strings

Associated malware family: Invisimole.

Targets: Windows PE.

It defines 9 patterns (4 text, 5 hex, 0 regex).

Summary generated from the rule's metadata and condition.

Rule source

Download .yar

Includes the imports and 1 rule(s) it depends on needed to compile it on its own.

apt-windows-invisimole.yarBSD 2-Clause License

private rule ESET_Invisimole_Blob_PRIVATE
{
	meta:
		description = "Detects InvisiMole blobs by magic values"
		author = "ESET Research"
		id = "6a179d91-50f1-5400-b141-0f162efd2431"
		date = "2021-05-17"
		modified = "2021-05-17"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/invisimole/invisimole.yar#L34-L52"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		logic_hash = "8bddaf874da58fbe6362498f8979b511f39531fe2b98d4be8c099bdafb6d0067"
		score = 75
		quality = 80
		tags = ""
		license = "BSD 2-Clause"
		version = "1"

	strings:
		$magic_old_32 = {F9 FF D0 DE}
		$magic_old_64 = {64 FF D0 DE}
		$magic_new_32 = {86 DA 11 CE}
		$magic_new_64 = {64 DA 11 CE}

	condition:
		($magic_old_32 at 0 ) or ( $magic_old_64 at 0 ) or ( $magic_new_32 at 0 ) or ( $magic_new_64 at 0 )
}

rule ESET_Apt_Windows_Invisimole : FILE
{
	meta:
		description = "InvisiMole magic values, keys and strings"
		author = "ESET Research"
		id = "4d48996b-9792-57ba-a302-349220323712"
		date = "2021-05-17"
		modified = "2021-05-17"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/invisimole/invisimole.yar#L215-L255"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		logic_hash = "7a2cff9febe77d718089ba4e1a33f3487594588892e418cec685bf22b156fa2b"
		score = 75
		quality = 80
		tags = "FILE"
		license = "BSD 2-Clause"
		version = "1"

	strings:
		$s1 = "CryptProtectData"
		$s2 = "CryptUnprotectData"
		$s3 = {9E 01 3A AD}
		$s4 = "GET /getversion2a/%d%.2X%.2X/U%sN HTTP/1.1"
		$s5 = "PULSAR_LOADER.dll"
		$check_magic_old_32 = {3? F9 FF D0 DE}
		$check_magic_old_64 = {3? 64 FF D0 DE}
		$check_magic_new_32 = {81 3? 86 DA 11 CE}
		$check_magic_new_64 = {81 3? 64 DA 11 CE}

	condition:
		(( uint16( 0 ) == 0x5A4D ) or ESET_Invisimole_Blob_PRIVATE ) and ( any of ( $check_magic* ) ) and ( 2 of ( $s* ) )
}

Strings (9 patterns)

Identifier	Type	Value
$s1	text	"CryptProtectData"
$s2	text	"CryptUnprotectData"
$s3	hex	{9E 01 3A AD}
$s4	text	"GET /getversion2a/%d%.2X%.2X/U%sN HTTP/1.1"
$s5	text	"PULSAR_LOADER.dll"
$check_magic_old_32	hex	{3? F9 FF D0 DE}
$check_magic_old_64	hex	{3? 64 FF D0 DE}
$check_magic_new_32	hex	{81 3? 86 DA 11 CE}
$check_magic_new_64	hex	{81 3? 64 DA 11 CE}

Condition

(( uint16( 0 ) == 0x5A4D ) or ESET_Invisimole_Blob_PRIVATE ) and ( any of ( $check_magic* ) ) and ( 2 of ( $s* ) )

In plain words (Heuristic)

The file must start with “MZ” — a Windows executable (PE).
At least one pattern in ( $check_magic* ) must match.
At least 2 patterns in ( $s* ) must match.
Depends on the rule ESET_Invisimole_Blob_PRIVATE.

Test this rule in your browser

Drop a file to scan it with this rule using YARA-X compiled to WebAssembly. Nothing is uploaded.

Drop a file here or click to chooseScanned locally with YARA-X. Files up to 200 MB.

Open in editor

References

https://github.com/eset/malware-ioc/

Licence & attribution

Author: ESET Research

Source repository: ESET malware-ioc @ 17baf44964

Licence: BSD 2-Clause License (stated in the rule's own meta)

“BSD 2-Clause”

Original rule

Mirrored via YARA Forge 20260927, which prefixes rule names with the source and adds normalised meta fields.

Rule id: 4d48996b-9792-57ba-a302-349220323712

Metadata

version	1

Tags:FILE

ESET_Apt_Windows_Invisimole_CPL_Loader
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Apt_Windows_Invisimole_DNS_Downloader
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Apt_Windows_Invisimole_Logs
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Apt_Windows_Invisimole_SFX_Dropper
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Apt_Windows_Invisimole_RC2CL_Backdoor
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Apt_Windows_Invisimole_Wrapper_DLL
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Apt_Windows_Invisimole_C2
APT / threat actorESET malware-ioc· ESET Research· 2021-05-17
ESET_Invisimole_Blob_PRIVATE
MalwareESET malware-ioc· ESET Research· 2021-05-17

More Invisimole rules