YARA · Signature Base (Florian Roth / Nextron)

SIGNATURE_BASE_MAL_EXE_Prestigeransomware

Detection for Prestige Ransomware

MalwarePrestigeSignature Base (Florian Roth / Nextron)Detection Rule License 1.1Compiles with YARA-X

Author: Silas Cutler, modfied by Florian Roth
Date: 2023-01-04
Modified: 2023-01-06
Score / Quality: 80 / 85

What this rule detects

Detection for Prestige Ransomware

Associated malware family: Prestige.

Targets: Windows PE.

It defines 6 patterns (6 text, 0 hex, 0 regex). YARA modules used: pe.

Summary generated from the rule's metadata and condition.

Rule source

Download .yar

Includes the imports needed to compile it on its own.

mal-exe-prestigeransomware.yarDetection Rule License 1.1

import "pe"

rule SIGNATURE_BASE_MAL_EXE_Prestigeransomware : FILE
{
	meta:
		description = "Detection for Prestige Ransomware"
		author = "Silas Cutler, modfied by Florian Roth"
		id = "5ac8033a-8b15-5abe-89d5-018a4fef9ab5"
		date = "2023-01-04"
		modified = "2023-01-06"
		reference = "https://www.microsoft.com/en-us/security/blog/2022/10/14/new-prestige-ransomware-impacts-organizations-in-ukraine-and-poland/"
		source_url = "https://github.com/Neo23x0/signature-base/blob/94a1c48d7ab499879287ff611dfe7f9c56376030/yara/gen_100days_of_yara_2023.yar#L171-L195"
		license_url = "https://github.com/Neo23x0/signature-base/blob/94a1c48d7ab499879287ff611dfe7f9c56376030/LICENSE"
		hash = "5fc44c7342b84f50f24758e39c8848b2f0991e8817ef5465844f5f2ff6085a57"
		logic_hash = "2f51ca71d28c8d0df8de22011e16919672d5f9d3f3d94594c5d0cbf7f1585a1e"
		score = 80
		quality = 85
		tags = "FILE"
		version = "1.0"
		DaysofYARA = "4/100"

	strings:
		$x_ransom_email = "Prestige.ranusomeware@Proton.me" wide
		$x_reg_ransom_note = "C:\\Windows\\System32\\reg.exe add HKCR\\enc\\shell\\open\\command /ve /t REG_SZ /d \"C:\\Windows\\Notepad.exe C:\\Users\\Public\\README\" /f" wide
		$ransom_message01 = "To decrypt all the data, you will need to purchase our decryption software." wide
		$ransom_message02 = "Contact us {}. In the letter, type your ID = {:X}." wide
		$ransom_message03 = "- Do not try to decrypt your data using third party software, it may cause permanent data loss." wide
		$ransom_message04 = "- Do not modify or rename encrypted files. You will lose them." wide

	condition:
		uint16( 0 ) == 0x5A4D and ( 1 of ( $x* ) or 2 of them or pe.imphash ( ) == "a32bbc5df4195de63ea06feb46cd6b55" )
}

Strings (6 patterns)

Identifier	Type	Value	Modifiers
$x_ransom_email	text	"Prestige.ranusomeware@Proton.me"	wide
$x_reg_ransom_note	text	"C:\\Windows\\System32\\reg.exe add HKCR\\enc\\shell\\open\\command /ve /t REG_SZ /d \"C:\\Windows\\Notepad.exe C:\\Users\\Public\\README\" /f"	wide
$ransom_message01	text	"To decrypt all the data, you will need to purchase our decryption software."	wide
$ransom_message02	text	"Contact us {}. In the letter, type your ID = {:X}."	wide
$ransom_message03	text	"- Do not try to decrypt your data using third party software, it may cause permanent data loss."	wide
$ransom_message04	text	"- Do not modify or rename encrypted files. You will lose them."	wide

Condition

uint16( 0 ) == 0x5A4D and ( 1 of ( $x* ) or 2 of them or pe.imphash ( ) == "a32bbc5df4195de63ea06feb46cd6b55" )

In plain words (Heuristic)

The file must start with “MZ” — a Windows executable (PE).
At least 1 patterns in ( $x* ) must match.
At least 2 patterns in the rule must match.
Uses the pe module.
Checks the PE import hash (imphash).

Test this rule in your browser

Drop a file to scan it with this rule using YARA-X compiled to WebAssembly. Nothing is uploaded.

Drop a file here or click to chooseScanned locally with YARA-X. Files up to 200 MB.

Open in editor

References

https://www.microsoft.com/en-us/security/blog/2022/10/14/new-prestige-ransomware-impacts-organizations-in-ukraine-and-poland/

Sample hashes

Hashes of samples the author lists in the rule's meta (look them up in your threat-intelligence platform).

5fc44c7342b84f50f24758e39c8848b2f0991e8817ef5465844f5f2ff6085a57

Licence & attribution

Author: Silas Cutler, modfied by Florian Roth

Source repository: Signature Base (Florian Roth / Nextron) @ 94a1c48d7a

Licence: Detection Rule License 1.1 (repository licence)

Original rule

Mirrored via YARA Forge 20260927, which prefixes rule names with the source and adds normalised meta fields.

Rule id: 5ac8033a-8b15-5abe-89d5-018a4fef9ab5

Metadata

version	1.0
DaysofYARA	4/100

Tags:FILE

MALPEDIA_Win_Prestige_Auto
MalwareMalpedia signator rules· Felix Bilstein - yara-signator at cocacoding dot com· 2026-05-04
SIGNATURE_BASE_MAL_EXE_Royalransomware
MalwareSignature Base (Florian Roth / Nextron)· Silas Cutler, modfied by Florian Roth· 2023-01-03