SEKOIA_Rat_Win_Borat

rule SEKOIA_Rat_Win_Borat : FILE
{
	meta:
		description = "Detect the Borat RAT besed on specific strings"
		author = "Sekoia.io"
		id = "9f8badb3-ee8b-45d9-8515-c847351bb1f5"
		date = "2022-04-08"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/rat_win_borat.yar#L1-L25"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "53d6d9fe6b3218d97079e624379863d927d0b783b24acbda359b18daafb5162e"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str0 = "BoratRatMutex_Sa8XOfH1BudX" ascii
		$str1 = "BoratRat.exe" ascii
		$str2 = "BoratRat" ascii
		$str3 = "CN=BoratRat" wide
		$str4 = "Sending plugun to " wide
		$str5 = "Save recorded file fail " wide
		$str6 = "Sa8XOfH1BudX" wide
		$str7 = "Alert when process activive." wide
		$str8 = "disableDefedner" wide
		$str9 = "bin\\Ransomware.dll" wide
		$str10 = "disableDefedner" wide

	condition:
		uint16( 0 ) == 0x5A4D and 7 of them
}