SEKOIA_Rat_Win_Babylon

rule SEKOIA_Rat_Win_Babylon : FILE
{
	meta:
		description = "Finds Babylon RAT samples based on specific strings"
		author = "Sekoia.io"
		id = "ba9ab80a-ad7e-4746-aff2-9328440cbb25"
		date = "2023-08-22"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/rat_win_babylon.yar#L1-L27"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "142f10e519561d6552c9cb8d267280b9ede203a2f4723d904ab07217b0565bd1"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "ParadoxRAT_Client" ascii
		$str02 = "*** in database %s ***" ascii
		$str03 = "\\drivers\\etc\\HOSTS" ascii
		$str04 = "Babylon RAT Client" wide
		$str05 = "ClipBoard.txt" wide
		$str06 = "a,ccs=UTF-16LE" wide
		$str07 = "[%02d/%02d/%d %02d:%02d:%02d] [%s] (%s):" wide
		$str08 = "Update Failed [OpenProcess]..." wide
		$str09 = "DoS Already Active..." wide
		$str10 = "File Download and Execution Failed..." wide
		$str11 = "LgDError33x98dGetProcAddress" wide
		$str12 = "FriendlyName" wide
		$str13 = "@SPYNET" wide

	condition:
		uint16( 0 ) == 0x5a4d and 8 of ( $str* )
}