SEKOIA_Rat_Win_Asyncrat

rule SEKOIA_Rat_Win_Asyncrat : FILE
{
	meta:
		description = "Detect AsyncRAT based on specific strings"
		author = "Sekoia.io"
		id = "d698e4a1-77ff-4cd7-acb3-27fb16168ceb"
		date = "2023-01-25"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/rat_win_asyncrat.yar#L1-L26"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "5e35b034ba1761fae780429be377b70ae8ce62273670042ff067c38ed8bb5a9e"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "get_ActivatePong" ascii
		$str02 = "get_SslClient" ascii
		$str03 = "get_TcpClient" ascii
		$str04 = "get_SendSync" ascii
		$str05 = "get_IsConnected" ascii
		$str06 = "set_UseShellExecute" ascii
		$str07 = "Pastebin" wide
		$str08 = "Select * from AntivirusProduct" wide
		$str09 = "Stub.exe" wide
		$str10 = "timeout 3 > NUL" wide
		$str11 = "/c schtasks /create /f /sc onlogon /rl highest /tn " wide
		$str12 = "\\nuR\\noisreVtnerruC\\swodniW\\tfosorciM\\erawtfoS" wide

	condition:
		uint16( 0 ) == 0x5A4D and 9 of them
}