SEKOIA_Ransomware_Win_Dodo_2023

rule SEKOIA_Ransomware_Win_Dodo_2023 : FILE
{
	meta:
		description = "Rule to detect Dodo ransomware samples."
		author = "Sekoia.io"
		id = "190977d4-5a7a-4e15-8f90-085f82ec56c8"
		date = "2023-02-13"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/ransomware_win_dodo_2023.yar#L1-L22"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		hash = "aee45cc2540d49a28e765c30f1c4d0b853c1a74ea2260bd7614ece8e54c3bcb3"
		logic_hash = "01924360ef4bbecd220439290eba22838a3977793fdebd0ef0be74c342c0d152"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$s1 = "DODOCRYPTER" ascii wide
		$s2 = "dodov2" ascii wide
		$s3 = "dodov2SPREAD.exe" ascii wide
		$s4 = "dodov2_readit.txt" ascii wide
		$s5 = "WELCOME, DODO has returned" ascii wide
		$s6 = "Monero Address: 442n8nf9zojie1JdkZqxDQJFDumBEgZmVZozLdYd5jVPSMws2oUPvNLJKca6JKojyA7zDCZCnMyYnKbY1JLNsbzWK6HNNqW" ascii wide
		$s7 = "The price for the software is $15. Payment can be made in Bitcoin or XMR." ascii wide

	condition:
		uint16be( 0 ) == 0x4d5a and 4 of them
}