SEKOIA_Loader_Win_Aresloader

rule SEKOIA_Loader_Win_Aresloader : FILE
{
	meta:
		description = "Finds AresLoader samples based on characteristic strings"
		author = "Sekoia.io"
		id = "bf5070fc-c8ca-4458-8702-cd1830667b7a"
		date = "2023-05-02"
		modified = "2024-12-19"
		reference = "https://blog.cyble.com/2023/04/28/citrix-users-at-risk-aresloader-spreading-through-disguised-gitlab-repo/"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/loader_win_aresloader.yar#L1-L28"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "2edbb625394506e865580373d5c3454b4fa201183c84d247b4373f24e25f5fd4"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "{\\\"ip\\\": '%s', \\\"UID\\\": '%s', \\\"geo\\\": '%s', \\\"service\\\": '%s', \\\"owner_token\\\": '%s'}" ascii
		$str02 = "AresLdr_v_3" ascii
		$str03 = "https://ipinfo.io/ip" ascii
		$str04 = "C:\\Users\\%s\\AppData\\Roaming\\%s\\%s" ascii
		$str05 = "/manager/payload" ascii
		$str06 = "/manager/loader" ascii
		$str07 = "/manager/legit" ascii
		$str08 = "/manager/hvnc" ascii
		$str09 = "C%p %d V=%0X w=%ld %s" ascii
		$str10 = "rundll32.exe %s,%s" ascii
		$str11 = "%startinfo" ascii
		$str12 = "%managedapp" ascii
		$str13 = "%has_cctor" ascii

	condition:
		uint16( 0 ) == 0x5A4D and 5 of them
}