SEKOIA_Infostealer_Win_Meduzastealer

rule SEKOIA_Infostealer_Win_Meduzastealer : FILE
{
	meta:
		description = "Finds MeduzaStealer samples based on specific strings"
		author = "Sekoia.io"
		id = "1276f485-aa5d-491b-89d8-77f98dc496e1"
		date = "2023-06-20"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_meduzastealer.yar#L1-L26"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "e81a5a9611662422eb7a87c0c1a370cee6f138fd6169225d969b669337d91a06"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "emoji" ascii
		$str02 = "%d-%m-%Y, %H:%M:%S" ascii
		$str03 = "[UTC" ascii
		$str04 = "user_name" ascii
		$str05 = "computer_name" ascii
		$str06 = "timezone" ascii
		$str07 = "current_path()" ascii
		$str08 = "[json.exception." ascii
		$str09 = "GDI32.dll" ascii
		$str10 = "GdipGetImageEncoders" ascii
		$str11 = "GetGeoInfoA" ascii

	condition:
		uint16( 0 ) == 0x5a4d and 8 of them and filesize > 500KB
}