SEKOIA_Infostealer_Win_Leaf

rule SEKOIA_Infostealer_Win_Leaf : FILE
{
	meta:
		description = "Find samples of Leaf Stealer based on specific strings"
		author = "Sekoia.io"
		id = "17d8e384-1092-4f27-b4f7-c0c0f7efcaa3"
		date = "2023-02-07"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_leaf.yar#L1-L32"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "f8c0ff694c9f7a02613000d85a40f6b400dcca60711e589f7ccd3546f571aea6"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "Leaf $tealer" ascii
		$str02 = "KiwiFolder" ascii
		$str03 = "key_wordsFiles" ascii
		$str04 = "**[Click to copy](https://superfurrycdn.nl/copy/" ascii
		$str05 = "Early_Verified_Bot_Developer" ascii
		$str06 = "getCookie.<locals>.<genexpr>" ascii
		$str07 = "C:\\Program Files (x86)\\Steam\\config" ascii
		$str08 = "[crunchyroll](https://crunchyroll.com)" ascii
		$str09 = "-m pip install" ascii
		$str10 = "taskkill /im " ascii
		$str11 = "/loginusers.vdf" ascii
		$str12 = "mot_de_passe" ascii
		$str13 = "Interesting files found on user PC" ascii
		$str14 = "NationsGlory/Local Storage/leveldb" ascii
		$str15 = "wppassw.txt" ascii
		$str16 = "wpcook.txt" ascii
		$str17 = "ProcesName < 1 >" ascii
		$str18 = "Metamask_" ascii

	condition:
		uint16( 0 ) == 0x5A4D and 10 of them
}