SEKOIA_Infostealer_Win_Edgeguard

rule SEKOIA_Infostealer_Win_Edgeguard : FILE
{
	meta:
		description = "Finds EdgeGuard Stealer samples based on specific strings"
		author = "Sekoia.io"
		id = "bbdb362f-d235-48f8-8fa5-d340d4e3e3f0"
		date = "2023-08-22"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_edgeguard.yar#L1-L32"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "11396aea2e166456ec8311f95a8037aac41f69caf3158f8c19cb0c38327842d6"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "main.downloadnecessary" ascii
		$str02 = "main.extractchromepasswords" ascii
		$str03 = "main.extracttasksch" ascii
		$str04 = "main.BrowserDownloadsViewExtract" ascii
		$str05 = "main.stealmetamask" ascii
		$str06 = "main.stealexoduswallet" ascii
		$str07 = "main.moveatomic" ascii
		$str08 = "main.movefirefoxcookies" ascii
		$str09 = "main.movepasswords" ascii
		$str10 = "main.FinallyZIPIPFolder" ascii
		$str11 = "edgeguard.business" ascii
		$str12 = "/License.XenArmor" ascii
		$str13 = "/TaskSchedulerView.exe" ascii
		$str14 = "/BrowsingHistoryView.exe" ascii
		$str15 = "/outlookfiles/starter.exe" ascii
		$str16 = "/outlookfiles/External.zip" ascii
		$str17 = "/outlookfiles/XenManager.dll" ascii
		$str18 = "/outlookfiles/EmailPasswordRecoveryPro.exe" ascii

	condition:
		uint16( 0 ) == 0x5a4d and 10 of ( $str* )
}