SEKOIA_Infostealer_Win_Ducklogs

rule SEKOIA_Infostealer_Win_Ducklogs : FILE
{
	meta:
		description = "Detects DuckLogs based on specific strings"
		author = "Sekoia.io"
		id = "165c7d3d-de7e-4d71-b94a-8ab4a0e5ddd5"
		date = "2022-12-01"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_ducklogs.yar#L1-L30"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "5db1a5595ec41488da620606bbcb36d0d686f9d6b7a0479439c53625df0886a0"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$dck = "DuckLogs" ascii wide
		$str01 = "CheckRemoteDebuggerPresent" ascii
		$str02 = "MozGlueNotFound" ascii
		$str03 = "get_DecryptedPassword" ascii
		$str04 = "get_Extension" ascii
		$str05 = "set_UseShellExecute" ascii
		$str06 = "FirefoxPasswords" ascii
		$str07 = "GetAllGeckoCookies" ascii
		$str08 = "GetAllBlinkDownloadsBy" ascii
		$str09 = "Grabbers" ascii
		$str10 = "Utility" ascii
		$str11 = "Persistance" ascii
		$str12 = "Clipboard" ascii
		$str13 = "WaterfoxGrabber" ascii
		$str14 = "AvastGrabber" ascii

	condition:
		uint16( 0 ) == 0x5A4D and ( ( #dck > 4 and 2 of ( $str* ) ) or 12 of them )
}