SEKOIA_Infostealer_Win_Cinoshistealer

rule SEKOIA_Infostealer_Win_Cinoshistealer : FILE
{
	meta:
		description = "Finds Cinoshi Stealer samples based on specific strings, or PE resources"
		author = "Sekoia.io"
		id = "2e9c066b-d5e3-4a25-8954-c10af285bcd3"
		date = "2023-06-23"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_cinoshistealer.yar#L1-L29"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "c4d8418a7bd1bf205295100d993562c89b17b80889cad5aac7a74f89e66543ce"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "Anaida.exe" ascii wide
		$str02 = "Anaida.pdb" ascii
		$str03 = "embedder_download_data" ascii
		$str04 = "date_password_modified" ascii
		$str05 = "card_number_encrypted" ascii
		$str06 = "set_UseZip64WhenSaving" ascii
		$str07 = "set_CommandText" ascii
		$str08 = "Nss3CouldNotBeLoaded" ascii
		$str09 = "formhistory.sqlite" wide
		$str10 = "logins.json" wide
		$str11 = "\\nss3.dll" wide
		$str12 = "\\cookies.sqlite" wide
		$str13 = "\\places.sqlite" wide
		$str14 = "\\autofill-profiles.json" wide

	condition:
		uint16( 0 ) == 0x5a4d and 9 of them and filesize > 400KB
}