SEKOIA_Infostealer_Win_Blustealer

rule SEKOIA_Infostealer_Win_Blustealer : FILE
{
	meta:
		description = "Detect the BluStealer infostealer based on characteristic strings"
		author = "Sekoia.io"
		id = "a56b3c12-9d83-4a0b-81e8-43332e64d599"
		date = "2022-10-05"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_blustealer.yar#L1-L29"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "fc7c11a9ddd21228aa773da6054220211327727a87d48008b7edb202c48666d8"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$cha01 = "@top\\LOGGERS\\DARKCLOUD" wide
		$cha02 = "===============DARKCLOUD===============" wide
		$cha03 = "#######################################DARKCLOUD#######################################" wide
		$cha04 = "fireballsabadafirebricksfisherboat" ascii
		$cha05 = "Moonchild Pro2ductions" wide
		$str01 = "\\Microsoft\\Windows\\Templates\\credentials.txt" wide
		$str02 = "\\NETGATE Technologies\\BlackHawK\\Profiles" wide
		$str03 = "SysWOW64\\winsqlite3.dll" wide
		$str04 = "HKCU\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\RunOnce\\*RD_" wide
		$str05 = "Expiry Date;" wide
		$str06 = "SELECT c0subject, c3author, c4recipients, c1body  FROM messagesText_content" wide
		$str07 = "http://www.mediacollege.com/internet/utilities/show-ip.shtml" wide
		$str08 = "\\163MailContacts.txt" wide
		$key_0 = {ba ?? ?? 40 00 8d 4?}

	condition:
		uint16( 0 ) == 0x5A4D and 2 of ( $cha* ) and 4 of ( $str* ) and $key_0
}