SEKOIA_Hacktool_Win_Cookiekatz

rule SEKOIA_Hacktool_Win_Cookiekatz : FILE
{
	meta:
		description = "Finds ChromeKatz (CookieKatz version) standalone samples based on the strings"
		author = "Sekoia.io"
		id = "a32769bb-4ec4-46c7-9402-21afdf8d4293"
		date = "2024-10-30"
		modified = "2024-12-19"
		reference = "https://github.com/Meckazin/ChromeKatz"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/hacktool_win_cookiekatz.yar#L1-L36"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		hash = "fef9fc33a788489af44b2f732c450d4ef018fbaced7f5471230b282dfd6f1169"
		logic_hash = "a030f551d0f3dedf0f19e22b415aa87dd1c43ab2242db8b5cad14ae6b7695b3a"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "CookieKatz.exe" ascii
		$str02 = "--utility-sub-type=network.mojom.NetworkService" wide
		$str03 = "chrome.dll" wide
		$str04 = "msedge.dll" wide
		$str05 = "msedgewebview2.exe" wide
		$str06 = "Failed to read cookie struct" wide
		$str07 = "Failed to read the root node from given address" wide
		$str08 = "Error reading left node" wide
		$str09 = "By Meckazin" ascii
		$str10 = "By default targets first available Chrome process" ascii
		$str11 = "Kittens love cookies too!" ascii
		$str12 = "Attempting to read the cookie value from address: 0x%p" ascii
		$str13 = "szCookieMonster" ascii
		$str14 = "[*] Targeting Chrome" ascii
		$str15 = "[*] Targeting Edge" ascii
		$str16 = "[*] This Cookie map was empty" ascii
		$str17 = "[+] Found browser process: %d" ascii wide
		$str18 = "[*] Targeting process PID: %d" wide
		$str19 = "[*] Found CookieMonster on 0x%p" wide
		$str20 = "[*] CookieMap should be found in address 0x%p" wide

	condition:
		uint16( 0 ) == 0x5A4D and 8 of them
}