SEKOIA_Hacktool_Impacket_Compiled_Binary

rule SEKOIA_Hacktool_Impacket_Compiled_Binary : FILE
{
	meta:
		description = "Detects generic PE embbeding impacket"
		author = "Sekoia.io"
		id = "43936dcc-0d74-43dd-996a-c27a28cef283"
		date = "2022-02-28"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/hacktool_impacket_compiled_binary.yar#L1-L36"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "133f9d0103774701894ea884bc2c52840b405fa21acb9ebab615816ec411b0bf"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$i1 = "impacket.crypto" fullword
		$i2 = "impacket.dcerpc" fullword
		$i3 = "impacket.ese" fullword
		$i4 = "impacket.hresult_errors" fullword
		$i5 = "impacket.krb5" fullword
		$i6 = "impacket.nmb" fullword
		$i7 = "impacket.nt_errors" fullword
		$i8 = "impacket.ntlm" fullword
		$i9 = "impacket.smb" fullword
		$i10 = "impacket.smb3" fullword
		$i11 = "impacket.smb3structs" fullword
		$i12 = "impacket.smbconnection" fullword
		$i13 = "impacket.spnego" fullword
		$i14 = "impacket.structure" fullword
		$i15 = "impacket.system_errors" fullword
		$i16 = "impacket.tds" fullword
		$i17 = "impacket.uuid" fullword
		$i18 = "impacket.version" fullword
		$i19 = "impacket.winregistry" fullword
		$py = "PYZ-00.pyz"

	condition:
		uint16be( 0 ) == 0x4d5a and filesize > 1MB and 3 of ( $i* ) and $py
}