SEKOIA_Hacktool_Dnscat2_Strings

rule SEKOIA_Hacktool_Dnscat2_Strings : FILE
{
	meta:
		description = "Detects DNSCat2 based on strings"
		author = "Sekoia.io"
		id = "9655cdd7-c7fe-4033-bdd9-bdfcfd2bf827"
		date = "2022-02-25"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/hacktool_dnscat2_strings.yar#L1-L22"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "40d906ca3a00f7d3e2f8d043dbbc77a2a57fd133f4812b863aec6d5a0f57a8c9"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$ = "Creating a exec('%s') session!"
		$ = "RROR parsing --dns"
		$ = "Got a ping request! Responding!"
		$ = "[Tunnel %d] Received %zd bytes"
		$ = "[Tunnel %d] connection to %s:%d"
		$ = "You'll need to use --dns server=<server>"
		$ = "Setting delay between packets to %dms"

	condition:
		( uint32be( 0 ) == 0x7f454c46 or uint16be( 0 ) == 0x4d5a ) and 3 of them
}