SEKOIA_Bot_Lin_Enemybot_April22

rule SEKOIA_Bot_Lin_Enemybot_April22 : FILE
{
	meta:
		description = "Detect enemybot based on command line observed in strings"
		author = "Sekoia.io"
		id = "5778c653-39ce-4f5d-b10b-1503b74e5041"
		date = "2022-04-14"
		modified = "2024-12-19"
		reference = "https://twitter.com/3xp0rtblog/status/137520616938452173://www.fortinet.com/blog/threat-research/enemybot-a-look-into-keksecs-latest-ddos-botnet"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/bot_lin_enemybot_april22.yar#L1-L26"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "18ea06e60259f8d7d639b0e4659f0f5e166e9589d617f5766c06968af5e56aa6"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$cmd0 = "wget http://%s/update.sh" ascii
		$cmd1 = "busybox wget http://%s/update.sh" ascii
		$cmd2 = "curl http://%s/update.sh" ascii
		$cmd3 = "chmod 777 update.sh" ascii
		$cmd4 = "rm -rf update.sh" ascii
		$str0 = "ENEMEYBOT" ascii xor
		$str1 = "KEKSEC" ascii xor
		$str2 = "/tmp/.pwned" ascii xor
		$str3 = "echo -e \"\x65\x6e\x65\x6d\x79"

	condition:
		( uint32( 0 ) == 0x464c457f or uint32( 0 ) == 0xfeedfacf ) and ( 4 of ( $cmd* ) or 2 of ( $str* ) )
}