SEKOIA_Apt_Shadowpad_First_Called_Function

rule SEKOIA_Apt_Shadowpad_First_Called_Function : FILE
{
	meta:
		description = "Detects entrypoint of shadowpad"
		author = "Sekoia.io"
		id = "3ce1ffd3-5c30-4b36-b7cc-c9fa873ebc25"
		date = "2023-01-30"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/apt_shadowpad_first_called_function.yar#L1-L36"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "a40db3fad01f4177973fd50bd489e5c4ff6d3592dfff063c2c31694007c31e0b"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$chunk_1 = {
        48 83 EC 28
        33 C9
        FF 15 ?? ?? ?? ??
        8B 80 ?? ?? ?? ??
        3B 05 ?? ?? ?? ??
        74 ??
        E8 ?? ?? ?? ??
        E8 ?? ?? ?? ??
        EB ??
        48 8B 0D ?? ?? ?? ??
        E8 ?? ?? ?? ??
        8B C8
        FF 15 ?? ?? ?? ??
        90
        B9 28 04 00 00
        FF 15 ?? ?? ?? ??
        90
        48 83 C4 28
        C3
        }

	condition:
		uint16be( 0 ) == 0x4d5a and all of them
}