YARA · ESET malware-ioc

ESET_IIS_Group12

Detects Group 12 native IIS malware family

MalwareESET malware-iocBSD 2-Clause LicenseCompiles with YARA-X

Author: ESET Research
Date: 2021-08-04
Score / Quality: 75 / 78

What this rule detects

Detects Group 12 native IIS malware family

It defines 21 patterns (19 text, 2 hex, 0 regex). YARA modules used: pe.

Summary generated from the rule's metadata and condition.

Rule source

Download .yar

Includes the imports and 1 rule(s) it depends on needed to compile it on its own.

iis-group12.yarBSD 2-Clause License

import "pe"

private rule ESET_IIS_Native_Module_PRIVATE : FILE
{
	meta:
		description = "Signature to match an IIS native module (clean or malicious)"
		author = "ESET Research"
		id = "e3bacdc8-fde1-5e83-ac94-79fc345e888d"
		date = "2021-08-04"
		modified = "2021-08-04"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/badiis/badiis.yar#L34-L92"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		logic_hash = "5a388dc3253df606e2648d1f9c018e6dde373bbddce66dba69b7aecdd95bac18"
		score = 75
		quality = 55
		tags = "FILE"
		license = "BSD 2-Clause"
		version = "1"

	strings:
		$e1 = "This module subscribed to event"
		$e2 = "CHttpModule::OnBeginRequest"
		$e3 = "CHttpModule::OnPostBeginRequest"
		$e4 = "CHttpModule::OnAuthenticateRequest"
		$e5 = "CHttpModule::OnPostAuthenticateRequest"
		$e6 = "CHttpModule::OnAuthorizeRequest"
		$e7 = "CHttpModule::OnPostAuthorizeRequest"
		$e8 = "CHttpModule::OnResolveRequestCache"
		$e9 = "CHttpModule::OnPostResolveRequestCache"
		$e10 = "CHttpModule::OnMapRequestHandler"
		$e11 = "CHttpModule::OnPostMapRequestHandler"
		$e12 = "CHttpModule::OnAcquireRequestState"
		$e13 = "CHttpModule::OnPostAcquireRequestState"
		$e14 = "CHttpModule::OnPreExecuteRequestHandler"
		$e15 = "CHttpModule::OnPostPreExecuteRequestHandler"
		$e16 = "CHttpModule::OnExecuteRequestHandler"
		$e17 = "CHttpModule::OnPostExecuteRequestHandler"
		$e18 = "CHttpModule::OnReleaseRequestState"
		$e19 = "CHttpModule::OnPostReleaseRequestState"
		$e20 = "CHttpModule::OnUpdateRequestCache"
		$e21 = "CHttpModule::OnPostUpdateRequestCache"
		$e22 = "CHttpModule::OnLogRequest"
		$e23 = "CHttpModule::OnPostLogRequest"
		$e24 = "CHttpModule::OnEndRequest"
		$e25 = "CHttpModule::OnPostEndRequest"
		$e26 = "CHttpModule::OnSendResponse"
		$e27 = "CHttpModule::OnMapPath"
		$e28 = "CHttpModule::OnReadEntity"
		$e29 = "CHttpModule::OnCustomRequestNotification"
		$e30 = "CHttpModule::OnAsyncCompletion"
		$e31 = "CGlobalModule::OnGlobalStopListening"
		$e32 = "CGlobalModule::OnGlobalCacheCleanup"
		$e33 = "CGlobalModule::OnGlobalCacheOperation"
		$e34 = "CGlobalModule::OnGlobalHealthCheck"
		$e35 = "CGlobalModule::OnGlobalConfigurationChange"
		$e36 = "CGlobalModule::OnGlobalFileChange"
		$e37 = "CGlobalModule::OnGlobalApplicationStart"
		$e38 = "CGlobalModule::OnGlobalApplicationResolveModules"
		$e39 = "CGlobalModule::OnGlobalApplicationStop"
		$e40 = "CGlobalModule::OnGlobalRSCAQuery"
		$e41 = "CGlobalModule::OnGlobalTraceEvent"
		$e42 = "CGlobalModule::OnGlobalCustomNotification"
		$e43 = "CGlobalModule::OnGlobalThreadCleanup"
		$e44 = "CGlobalModule::OnGlobalApplicationPreload"

	condition:
		uint16( 0 ) == 0x5A4D and pe.exports ( "RegisterModule" ) and any of ( $e* )
}

rule ESET_IIS_Group12
{
	meta:
		description = "Detects Group 12 native IIS malware family"
		author = "ESET Research"
		id = "7278f2df-d18a-5d95-9c21-37906629a7f0"
		date = "2021-08-04"
		modified = "2021-08-04"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/badiis/badiis.yar#L457-L495"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		logic_hash = "8da03328e3702aff8ea5de77fc220f326030c31972d27c0bd9b5918dca550aba"
		score = 75
		quality = 78
		tags = ""
		license = "BSD 2-Clause"
		version = "1"

	strings:
		$s1 = "C:\\inetpub\\temp\\IIS Temporary Compressed Files\\"
		$s2 = "F5XFFHttpModule.dll"
		$s3 = "gtest_redir"
		$s4 = "\\cmd.exe" nocase
		$s5 = "iuuq;00"
		$s6 = "?xhost="
		$s7 = "&reurl="
		$s8 = "?jump=1"
		$s9 = "app|zqb"
		$s10 = "ifeng|ivc|sogou|so.com|baidu|google|youdao|yahoo|bing|118114|biso|gougou|sooule|360|sm|uc"
		$s11 = "sogou|so.com|baidu|google|youdao|yahoo|bing|gougou|sooule|360|sm.cn|uc"
		$s12 = "Hotcss/|Hotjs/"
		$s13 = "HotImg/|HotPic/"
		$s14 = "msf connect error !!"
		$s15 = "download ok !!"
		$s16 = "download error !! "
		$s17 = "param error !!"
		$s18 = "Real Path: "
		$s19 = "unknown cmd !"
		$b1 = {15 BD 01 2E [-] 5E 40 08 97 [-] CF 8C BE 30 [-] 28 42 C6 3B}
		$b2 = {E1 0A DC 39 [-] 49 BA 59 AB [-] BE 56 E0 57 [-] F2 0F 88 3E}

	condition:
		ESET_IIS_Native_Module_PRIVATE and 5 of them
}

Strings (21 patterns)

Identifier	Type	Value	Modifiers
$s1	text	"C:\\inetpub\\temp\\IIS Temporary Compressed Files\\"
$s2	text	"F5XFFHttpModule.dll"
$s3	text	"gtest_redir"
$s4	text	"\\cmd.exe"	nocase
$s5	text	"iuuq;00"
$s6	text	"?xhost="
$s7	text	"&reurl="
$s8	text	"?jump=1"
$s9	text	"app\|zqb"
$s10	text	"ifeng\|ivc\|sogou\|so.com\|baidu\|google\|youdao\|yahoo\|bing\|118114\|biso\|gougou\|sooule\|360\|sm\|uc"
$s11	text	"sogou\|so.com\|baidu\|google\|youdao\|yahoo\|bing\|gougou\|sooule\|360\|sm.cn\|uc"
$s12	text	"Hotcss/\|Hotjs/"
$s13	text	"HotImg/\|HotPic/"
$s14	text	"msf connect error !!"
$s15	text	"download ok !!"
$s16	text	"download error !! "
$s17	text	"param error !!"
$s18	text	"Real Path: "
$s19	text	"unknown cmd !"
$b1	hex	{15 BD 01 2E [-] 5E 40 08 97 [-] CF 8C BE 30 [-] 28 42 C6 3B}
$b2	hex	{E1 0A DC 39 [-] 49 BA 59 AB [-] BE 56 E0 57 [-] F2 0F 88 3E}

Condition

ESET_IIS_Native_Module_PRIVATE and 5 of them

In plain words (Heuristic)

At least 5 patterns in the rule must match.
Depends on the rule ESET_IIS_Native_Module_PRIVATE.

Test this rule in your browser

Drop a file to scan it with this rule using YARA-X compiled to WebAssembly. Nothing is uploaded.

Drop a file here or click to chooseScanned locally with YARA-X. Files up to 200 MB.

Open in editor

References

https://github.com/eset/malware-ioc/

Licence & attribution

Author: ESET Research

Source repository: ESET malware-ioc @ 17baf44964

Licence: BSD 2-Clause License (stated in the rule's own meta)

“BSD 2-Clause”

Original rule

Mirrored via YARA Forge 20260927, which prefixes rule names with the source and adds normalised meta fields.

Rule id: 7278f2df-d18a-5d95-9c21-37906629a7f0

Metadata

version	1

ESET_Richheaders_Lazarus_Nukesped_Iconicpayloads_3CX_Q12023
MalwareESET malware-ioc· ESET Research· 2023-03-31
ESET_Cw_Windows_Redline_Panel_Distinctive_Strings
MalwareESET malware-ioc· ESET Research· 2022-10-11
ESET_Cw_Windows_Redline_Panel_Prompts
MalwareESET malware-ioc· ESET Research· 2022-10-11
ESET_Cw_Windows_Redline_Panel_Status_Message_Strings
MalwareESET malware-ioc· ESET Research· 2022-10-11
ESET_Cw_Windows_Redline_Panel_Tab_Headers
MalwareESET malware-ioc· ESET Research· 2022-10-11
ESET_IIS_Group04_Rgdoor
MalwareESET malware-ioc· ESET Research· 2021-08-04
ESET_IIS_Group07_Iispy
MalwareESET malware-ioc· ESET Research· 2021-08-04
ESET_Invisimole_Blob_PRIVATE
MalwareESET malware-ioc· ESET Research· 2021-05-17