SEKOIA_Kimsuky_Konni_Dll

rule SEKOIA_Kimsuky_Konni_Dll : FILE
{
	meta:
		description = "Rule based on structure offset and file extension"
		author = "Sekoia.io"
		id = "6a20c492-e932-41bd-ac4a-01d35bfb0c49"
		date = "2022-09-12"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/kimsuky_konni_dll.yar#L1-L29"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "7099156decdfe35cde22958133d851479f12180fff7b5744af0c549ab8259636"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$ext_1 = ".zip" wide ascii fullword
		$ext_2 = ".cab" wide ascii fullword
		$ext_3 = ".rar" wide ascii fullword
		$ext_4 = ".ini" wide ascii fullword
		$ext_5 = ".dat" wide ascii fullword
		$offset_structure_1 = { 8d ?? 08 02 00 00 }
		$offset_structure_2 = { 8d ?? 10 04 00 00 }
		$offset_structure_3 = { 8d ?? 18 06 00 00 }
		$offset_structure_4 = { 8d ?? 20 08 00 00 }
		$offset_structure_5 = { 8d ?? 28 0a 00 00 }
		$offset_structure_6 = { 89 ?? f8 11 00 00 }
		$offset_structure_7 = { 8d ?? fc 11 00 00 }
		$offset_structure_8 = { 89 ?? 0c 12 00 00 }
		$offset_structure_9 = { 89 ?? 10 12 00 00 }

	condition:
		uint16be( 0 ) == 0x4d5a and filesize < 11MB and all of them
}