SEKOIA_Infostealer_Win_Aurora_Str

import "pe"

rule SEKOIA_Infostealer_Win_Aurora_Str : FILE
{
	meta:
		description = "Finds Aurora botnet samples based on characteristic strings."
		author = "Sekoia.io"
		id = "1f4391b8-700f-4702-9ef6-68ce3d55a176"
		date = "2022-07-21"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_aurora_str.yar#L3-L34"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "745443bb58f00cb09a1f323f530219913eaaf0d0e71c9a25af2072006f8c5f92"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "Logs.tar" ascii
		$str02 = "*main.StealerData" ascii
		$str03 = "AppData\\Roaming\\Armory" ascii
		$str04 = "AppData\\Local\\BraveSoftware\\Brave-Browser\\User Data" ascii
		$str05 = "github.com/TheTitanrain/w32" ascii
		$str06 = "github.com/mattn/go-sqlite3" ascii
		$str07 = "ScreenShot" ascii
		$str08 = "*sql.stmtConnGrabber" ascii
		$str09 = "Default\\Network\\Cookies" ascii
		$str10 = "BuildID" ascii
		$str11 = "Clipper" ascii
		$str12 = "GeoPos" ascii
		$str13 = "AppData\\Roaming\\Exodus\\exodus.wallet" ascii
		$str14 = "FileGrabber\\Documents" ascii
		$str15 = "193.233.48." ascii
		$str16 = "ShellExecute" ascii
		$str17 = "crypto/aes.(*aesCipherGCM).Encrypt" ascii
		$str18 = "File-Download" ascii

	condition:
		uint16( 0 ) == 0x5A4D and ( 14 of them or pe.imphash ( ) == "8ee5c1c09f740fbe63e8b35dac5d6f70" or pe.imphash ( ) == "369b4f5b6c99674f15070689e1f675af" )
}