ESET_Cw_Windows_Redline_Panel_Tab_Headers

rule ESET_Cw_Windows_Redline_Panel_Tab_Headers : FILE
{
	meta:
		description = "Matches view headers in Redline Panel"
		author = "ESET Research"
		id = "44a95845-b0a3-59c1-8188-86d415eff0bf"
		date = "2022-10-11"
		modified = "2024-11-12"
		reference = "https://github.com/eset/malware-ioc/"
		source_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/redline/redline.yar#L32-L55"
		license_url = "https://github.com/eset/malware-ioc/blob/17baf44964a77368e9149f4f593eb098beddf1c5/LICENSE"
		hash = "a154dfaedc237c047f419eb6884dab1ef4e2a17d"
		logic_hash = "3198aa9df2814a5f1d5568c6eed5f3189b2f72b3928cc97645f9bf57eebab9ac"
		score = 75
		quality = 80
		tags = "FILE"
		license = "BSD 2-Clause"
		version = 2

	strings:
		$ = "RedLine | Log In"
		$ = "RedLine | Autofilles Viewer"
		$ = "RedLine | Choose Browser"
		$ = "RedLine | Cookie Viewer"
		$ = "RedLine | Credit Card Viewer"
		$ = "RedLine | Files Viewer"
		$ = "RedLine | Log saver"
		$ = "RedLine | System Info Viewer"

	condition:
		uint16( 0 ) == 0x5A4D and 6 of them
}