YARA · CAPE Sandbox (CAPEv2)

CAPE_Zloader

Zloader Payload

GénériqueCAPE Sandbox (CAPEv2)GNU General Public License v3.0Compile avec YARA-X

Auteur: kevoreilly, enzok
Date: 2020-04-04
Modifiée: 2025-12-09
Score / Qualité: 75 / 70

Ce que détecte cette règle

Zloader Payload

Cibles : PE Windows.

Elle définit 7 motifs (0 texte, 7 hex, 0 regex).

Résumé généré à partir des métadonnées et de la condition de la règle.

Source de la règle

Télécharger .yar

zloader.yarGNU General Public License v3.0

rule CAPE_Zloader : FILE
{
	meta:
		description = "Zloader Payload"
		author = "kevoreilly, enzok"
		id = "a4250532-ddfc-58c2-bbae-82cc201d0c5d"
		date = "2020-04-04"
		modified = "2025-12-09"
		reference = "https://github.com/kevoreilly/CAPEv2"
		source_url = "https://github.com/kevoreilly/CAPEv2/blob/6b15e76f28cd83fd1187da6c9aaaad2174255356/data/yara/CAPE/Zloader.yar#L1-L18"
		license_url = "https://github.com/kevoreilly/CAPEv2/blob/6b15e76f28cd83fd1187da6c9aaaad2174255356/LICENSE"
		hash = "adbd0c7096a7373be82dd03df1aae61cb39e0a155c00bbb9c67abc01d48718aa"
		logic_hash = "525670973b67aac048199529c97d6be00b0a8cca9bc90deb647366d92a5ea540"
		score = 75
		quality = 70
		tags = "FILE"
		cape_type = "Zloader Payload"

	strings:
		$rc4_init = {31 [1-3] 66 C7 8? 00 01 00 00 00 00 90 90 [0-5] 8? [5-90] 00 01 00 00 [0-15] (74|75)}
		$decrypt_conf = {83 C4 04 84 C0 74 5? E8 [4] E8 [4] E8 [4] E8 [4] ?8 [4] ?8 [4] ?8}
		$decrypt_conf_1 = {48 8d [5-11] e8 [4] 48 [3-4] 48 [3-4] 48 [6] E8}
		$decrypt_conf_2 = {48 8d [5] 4? [5] e8 [4] 48 [3-4] 48 8d [5] E8 [4] 48}
		$decrypt_key_1 = {66 89 C2 4? 8D 0D [3] 00 4? B? FC 03 00 00 E8 [4] 4? 83 C4 [1-2] C3}
		$decrypt_key_2 = {48 8d 0d [3] 00 66 89 ?? 4? 89 F0 4? [2-5] E8 [4-5] 4? 83 C4}
		$decrypt_key_3 = {48 8d 0d [3] 00 e8 [4] 66 89 [3] b? [4] e8 [4] 66 8b}

	condition:
		uint16( 0 ) == 0x5A4D and 1 of ( $decrypt_conf* ) and ( 1 of ( $decrypt_key* ) or $rc4_init )
}

Chaînes (7 motifs)

Identifiant	Type	Valeur
$rc4_init	hex	{31 [1-3] 66 C7 8? 00 01 00 00 00 00 90 90 [0-5] 8? [5-90] 00 01 00 00 [0-15] (74\|75)}
$decrypt_conf	hex	{83 C4 04 84 C0 74 5? E8 [4] E8 [4] E8 [4] E8 [4] ?8 [4] ?8 [4] ?8}
$decrypt_conf_1	hex	{48 8d [5-11] e8 [4] 48 [3-4] 48 [3-4] 48 [6] E8}
$decrypt_conf_2	hex	{48 8d [5] 4? [5] e8 [4] 48 [3-4] 48 8d [5] E8 [4] 48}
$decrypt_key_1	hex	{66 89 C2 4? 8D 0D [3] 00 4? B? FC 03 00 00 E8 [4] 4? 83 C4 [1-2] C3}
$decrypt_key_2	hex	{48 8d 0d [3] 00 66 89 ?? 4? 89 F0 4? [2-5] E8 [4-5] 4? 83 C4}
$decrypt_key_3	hex	{48 8d 0d [3] 00 e8 [4] 66 89 [3] b? [4] e8 [4] 66 8b}

Condition

uint16( 0 ) == 0x5A4D and 1 of ( $decrypt_conf* ) and ( 1 of ( $decrypt_key* ) or $rc4_init )

En clair (Heuristique)

Le fichier doit commencer par « MZ » — un exécutable Windows (PE).
Au moins 1 motifs de ( $decrypt_conf* ) doivent être trouvés.
Au moins 1 motifs de ( $decrypt_key* ) doivent être trouvés.
Le motif $rc4_init doit être présent.

Tester cette règle dans votre navigateur

Déposez un fichier pour le scanner avec cette règle grâce à YARA-X compilé en WebAssembly. Rien n’est envoyé.

Déposez un fichier ici ou cliquez pour choisirScanné localement avec YARA-X. Fichiers jusqu’à 200 Mo.

Ouvrir dans l’éditeur

Références

https://github.com/kevoreilly/CAPEv2

Hashes d’échantillons

Hashes des échantillons listés par l’auteur dans les métadonnées de la règle (à rechercher dans votre plateforme de threat intelligence).

adbd0c7096a7373be82dd03df1aae61cb39e0a155c00bbb9c67abc01d48718aa

Licence et attribution

Auteur : kevoreilly, enzok

Dépôt source : CAPE Sandbox (CAPEv2) @ 6b15e76f28

Licence : GNU General Public License v3.0 (licence du dépôt)

Mention de copyright : Cuckoo Sandbox is copyrighted by the Cuckoo Foundation.

Règle d’origine

Reprise via YARA Forge 20260927, qui préfixe les noms de règles par la source et ajoute des champs meta normalisés.

Identifiant de règle: a4250532-ddfc-58c2-bbae-82cc201d0c5d

Métadonnées

cape_type	Zloader Payload

Tags:FILE