SEKOIA_Tool_Win_Sharpshares

rule SEKOIA_Tool_Win_Sharpshares : FILE
{
	meta:
		description = "Finds sharpshares EXE based on strings"
		author = "Sekoia.io"
		id = "ef90d573-12f8-4216-9a9e-96e7d1e841d0"
		date = "2024-06-10"
		modified = "2024-12-19"
		reference = "https://github.com/mitchmoser/SharpShares/releases"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/tool_win_sharpshares.yar#L1-L26"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "6aa96d7c24638451bde98497cc7c844c87612d81cc7826113729c80bd5180442"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "<GetAllShares>b__0" ascii
		$str02 = "<SearchLDAP>b__0_0" ascii
		$str03 = "get_AccessControlType" ascii
		$str04 = "get_IdentityReference" ascii
		$str05 = "get_PropertiesToLoad" ascii
		$str06 = "SharpShares\\obj\\Release\\SharpShares.pdb" ascii
		$str07 = "/filter:SYSVOL,NETLOGON,IPC$,PRINT$" wide
		$str08 = "/threads:50 /ldap:servers" wide
		$str09 = "SharpShares.exe" ascii wide
		$str10 = "[+] LDAP Search Results:" wide
		$str11 = "[+] Finished Enumerating Shares" wide

	condition:
		uint16( 0 ) == 0x5A4D and 6 of them
}