SEKOIA_Infostealer_Win_Monster_Stub

rule SEKOIA_Infostealer_Win_Monster_Stub : FILE
{
	meta:
		description = "Finds Monster Stealer stub (Python payload) based on specific strings."
		author = "Sekoia.io"
		id = "10d27d49-79ae-4edc-8c30-35506bdf2c42"
		date = "2024-08-07"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_monster_stub.yar#L1-L31"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "d6362c54b1f56ffa878423fbb1a3f57508d20e06b573c732f892494178a49200"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "https://t.me/monster_free_cloud" ascii
		$str02 = "MonsterUpdateService" ascii
		$str03 = "Monster.exe" ascii
		$str04 = "schtasks /create /f /sc daily /ri 30 /tn" ascii
		$str05 = "C:\\ProgramData\\Microsoft\\Windows\\Start Menu\\Programs\\StartUp\\" ascii
		$str06 = "banned_uuids" ascii
		$str07 = "banned_computer_names" ascii
		$str08 = "banned_process" ascii
		$str09 = "register_X_browsers" ascii
		$str10 = "register_payload" ascii
		$str11 = "tiktok_sessions.txt" ascii
		$str12 = "spotify_sessions.txt" ascii
		$str13 = "network_info.txt" ascii
		$str14 = "lolz.guru" ascii
		$str15 = "echo ####System Info####" ascii
		$str16 = "echo ####Firewallinfo####" ascii
		$str17 = "/injection/main/injection.js" ascii

	condition:
		uint16( 0 ) == 0x5A4D and 10 of them
}