SEKOIA_Infostealer_Win_Stealc_Str_Oct24

rule SEKOIA_Infostealer_Win_Stealc_Str_Oct24 : FILE
{
	meta:
		description = "Finds Stealc standalone samples (or dumps) based on the strings"
		author = "Sekoia.io"
		id = "7448fafe-206c-4f9c-b5a3-cbabec12a45b"
		date = "2024-10-20"
		modified = "2024-12-19"
		reference = "https://github.com/SEKOIA-IO/Community"
		source_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/yara_rules/infostealer_win_stealc_str_oct24.yar#L1-L27"
		license_url = "https://github.com/SEKOIA-IO/Community/blob/a438a5901a211c2abdf75da9c93921ef187473d1/LICENSE.md"
		logic_hash = "4f7fece81c3fe1e56b57aed4030b48331b53443a200799046fe84c895b591a71"
		score = 75
		quality = 80
		tags = "FILE"
		version = "1.0"
		classification = "TLP:CLEAR"

	strings:
		$str01 = "-nop -c \"iex(New-Object Net.WebClient).DownloadString(" ascii
		$str02 = "Azure\\.IdentityService" ascii
		$str03 = "steam_tokens.txt" ascii
		$str04 = "\"encrypted_key\":\"" ascii
		$str05 = "prefs.js" ascii
		$str06 = "browser: FileZilla" ascii
		$str07 = "profile: null" ascii
		$str08 = "url:" ascii
		$str09 = "login:" ascii
		$str10 = "password:" ascii
		$str11 = "C:\\Program Files\\Google\\Chrome\\Application\\chrome.exe" ascii
		$str12 = "ChromeFuckNewCookies" ascii
		$str13 = "/c timeout /t 10 & del /f /q \"" ascii

	condition:
		uint16( 0 ) == 0x5A4D and 9 of them
}