DITEKSHEN_INDICATOR_TOOL_Edrsilencer

rule DITEKSHEN_INDICATOR_TOOL_Edrsilencer : FILE
{
	meta:
		description = "Detects EDRSilencer"
		author = "ditekshen"
		id = "29b6da1e-9138-5ee6-b9fd-d7b3c7f48626"
		date = "2020-11-06"
		modified = "2024-09-25"
		reference = "https://github.com/ditekshen/detection"
		source_url = "https://github.com/ditekshen/detection/blob/e76c93dcdedff04076380ffc60ea54e45b313635/yara/indicator_tools.yar#L1838-L1857"
		license_url = "https://github.com/ditekshen/detection/blob/e76c93dcdedff04076380ffc60ea54e45b313635/LICENSE.txt"
		logic_hash = "da00aced2608fd5e192397ef2346ac247f29f993995fb90189e05da60be15d13"
		score = 75
		quality = 75
		tags = "FILE"

	strings:
		$s1 = "block \"C:\\Windows\\System32\\curl.exe\"" ascii
		$s2 = "blockedr" fullword ascii
		$s3 = "edrProcess" fullword ascii
		$s4 = "BlockEdrProcessTraffic" fullword ascii
		$s5 = "isInEdrProcessList" fullword ascii
		$s6 = "EDRSilencer.c" fullword ascii
		$v1 = "elastic-agent.exe" fullword ascii nocase
		$v2 = "CybereasonAV.exe" fullword ascii nocase
		$v3 = "SentinelAgent.exe" fullword ascii nocase
		$v4 = "fortiedr.exe" fullword ascii nocase
		$v5 = "MsMpEng.exe" fullword ascii nocase
		$v6 = "CylanceSvc.exe" fullword ascii nocase

	condition:
		uint16( 0 ) == 0x5a4d and ( 4 of ( $s* ) or ( 3 of ( $s* ) and 1 of ( $v* ) ) )
}